Theory Weak_Cong_Sim_Pres

(* 
   Title: The Calculus of Communicating Systems   
   Author/Maintainer: Jesper Bengtson (jebe@itu.dk), 2012
*)
theory Weak_Cong_Sim_Pres
  imports Weak_Cong_Sim
begin

lemma actPres:
  fixes P    :: ccs
  and   Q    :: ccs
  and   Rel  :: "(ccs × ccs) set"
  and   a    :: name
  and   Rel' :: "(ccs × ccs) set"

  assumes "(P, Q) ∈ Rel"

  shows "α.(P) \<leadsto><Rel> α.(Q)"
using assms
by(fastsimp simp add: weakCongSimulation_def elim: actCases intro: weakCongAction)

lemma sumPres:
  fixes P   :: ccs
  and   Q   :: ccs
  and   Rel :: "(ccs × ccs) set"

  assumes "P \<leadsto><Rel> Q"
  and     "Rel ⊆ Rel'"
  and     "Id ⊆ Rel'"

  shows "P ⊕ R \<leadsto><Rel'> Q ⊕ R"
using assms
by(force simp add: weakCongSimulation_def elim: sumCases intro: weakCongSum1 weakCongSum2 transitionWeakCongTransition)

lemma parPres:
  fixes P   :: ccs
  and   Q   :: ccs
  and   Rel :: "(ccs × ccs) set"

  assumes "P \<leadsto><Rel> Q"
  and     "(P, Q) ∈ Rel"
  and     C1: "!!S T U. (S, T) ∈ Rel ==> (S \<parallel> U, T \<parallel> U) ∈ Rel'"

  shows "P \<parallel> R \<leadsto><Rel'> Q \<parallel> R"
proof(induct rule: weakSimI)
  case(Sim α QR)
  from `Q \<parallel> R \<longmapsto>α \<prec> QR`
  show ?case
  proof(induct rule: parCases)
    case(cPar1 Q')
    from `P \<leadsto><Rel> Q` `Q \<longmapsto>α \<prec> Q'` obtain P' where "P ==>α \<prec> P'" and "(P', Q') ∈ Rel" 
      by(rule weakSimE)
    from `P ==>α \<prec> P'` have "P \<parallel> R ==>α \<prec> P' \<parallel> R" by(rule weakCongPar1)
    moreover from `(P', Q') ∈ Rel` have "(P' \<parallel> R, Q' \<parallel> R) ∈ Rel'" by(rule C1)
    ultimately show ?case by blast
  next
    case(cPar2 R')
    from `R \<longmapsto>α \<prec> R'` have "R ==>α \<prec> R'" by(rule transitionWeakCongTransition)
    hence "P \<parallel> R ==>α \<prec> P \<parallel> R'" by(rule weakCongPar2)
    moreover from `(P, Q) ∈ Rel` have "(P \<parallel> R', Q \<parallel> R') ∈ Rel'" by(rule C1)
    ultimately show ?case by blast
  next
    case(cComm Q' R' α)
    from `P \<leadsto><Rel> Q` `Q \<longmapsto>α \<prec> Q'` obtain P' where "P ==>α \<prec> P'" and "(P', Q') ∈ Rel" 
      by(rule weakSimE)
    from `R \<longmapsto>(coAction α) \<prec> R'` have "R ==>(coAction α) \<prec> R'"
      by(rule transitionWeakCongTransition)
    with `P ==>α \<prec> P'` have "P \<parallel> R ==>τ \<prec> P' \<parallel> R'" using `α ≠ τ` 
      by(rule weakCongSync)
    moreover from `(P', Q') ∈ Rel` have "(P' \<parallel> R', Q' \<parallel> R') ∈ Rel'" by(rule C1)
    ultimately show ?case by blast
  qed
qed

lemma resPres:
  fixes P   :: ccs
  and   Rel :: "(ccs × ccs) set"
  and   Q   :: ccs
  and   x   :: name

  assumes "P \<leadsto><Rel> Q"
  and     "!!R S y. (R, S) ∈ Rel ==> ((|νy|)),R, (|νy|)),S) ∈ Rel'"

  shows "(|νx|)),P \<leadsto><Rel'> (|νx|)),Q"
using assms
by(fastsimp simp add: weakCongSimulation_def elim: resCases intro: weakCongRes)

lemma bangPres:
  fixes P    :: ccs
  and   Q    :: ccs
  and   Rel  :: "(ccs × ccs) set"
  and   Rel' :: "(ccs × ccs) set"

  assumes "(P, Q) ∈ Rel"
  and     C1: "!!R S. (R, S) ∈ Rel ==> R \<leadsto><Rel'> S"
  and     C2: "Rel ⊆ Rel'"

  shows "!P \<leadsto><bangRel Rel'> !Q"
proof(induct rule: weakSimI)
  case(Sim α Q')
  {
    fix Pa α Q'
    assume "!Q \<longmapsto>α \<prec> Q'" and "(Pa, !Q) ∈ bangRel Rel"
    hence "∃P'. Pa ==>α \<prec> P' ∧ (P', Q') ∈ bangRel Rel'"
    proof(nominal_induct arbitrary: Pa rule: bangInduct)
      case(cPar1 α Q')
      from `(Pa, Q \<parallel> !Q) ∈ bangRel Rel` 
      show ?case
      proof(induct rule: BRParCases)
        case(BRPar P R)
        from `(P, Q) ∈ Rel` have "P \<leadsto><Rel'> Q" by(rule C1)
        with `Q \<longmapsto>α \<prec> Q'` obtain P' where "P ==>α \<prec> P'" and "(P', Q') ∈ Rel'"
          by(blast dest: weakSimE)
        from `P ==>α \<prec> P'` have "P \<parallel> R ==>α \<prec> P' \<parallel> R" by(rule weakCongPar1)
        moreover from `(R, !Q) ∈ bangRel Rel` C2 have "(R, !Q) ∈ bangRel Rel'"
          by induct (auto intro: bangRel.BRPar bangRel.BRBang)
        with `(P', Q') ∈ Rel'` have "(P' \<parallel> R, Q' \<parallel> !Q) ∈ bangRel Rel'"
          by(rule bangRel.BRPar)
        ultimately show ?case by blast
      qed
    next
      case(cPar2 α Q')
      from `(Pa, Q \<parallel> !Q) ∈ bangRel Rel`
      show ?case
      proof(induct rule: BRParCases)
        case(BRPar P R)
        from `(R, !Q) ∈ bangRel Rel` obtain R' where "R ==>α \<prec> R'" and "(R', Q') ∈ bangRel Rel'" using cPar2
          by blast
        from `R ==>α \<prec> R'` have "P \<parallel> R ==>α \<prec> P \<parallel> R'" by(rule weakCongPar2)
        moreover from `(P, Q) ∈ Rel` `(R', Q') ∈ bangRel Rel'` C2 have "(P \<parallel> R', Q \<parallel> Q') ∈ bangRel Rel'" 
          by(blast intro: bangRel.BRPar)
        ultimately show ?case by blast
      qed
    next
      case(cComm a Q' Q'' Pa)
      from `(Pa, Q \<parallel> !Q) ∈ bangRel Rel`
      show ?case
      proof(induct rule: BRParCases)
        case(BRPar P R)
        from `(P, Q) ∈ Rel` have "P \<leadsto><Rel'> Q" by(rule C1)
        with `Q \<longmapsto>a \<prec> Q'` obtain P' where "P ==>a \<prec> P'" and "(P', Q') ∈ Rel'"
          by(blast dest: weakSimE)
        from `(R, !Q) ∈ bangRel Rel` obtain R' where "R ==>(coAction a) \<prec> R'" and "(R', Q'') ∈ bangRel Rel'" using cComm
          by blast
        from `P ==>a \<prec> P'` `R ==>(coAction a) \<prec> R'` `a ≠ τ` have "P \<parallel> R ==>τ \<prec> P' \<parallel> R'" by(rule weakCongSync)
        moreover from `(P', Q') ∈ Rel'` `(R', Q'') ∈ bangRel Rel'` have "(P' \<parallel> R', Q' \<parallel> Q'') ∈ bangRel Rel'"
          by(rule bangRel.BRPar)
        ultimately show ?case by blast
      qed
    next
      case(cBang α Q' Pa)
      from `(Pa, !Q) ∈ bangRel Rel`
      show ?case
      proof(induct rule: BRBangCases)
        case(BRBang P)
        from `(P, Q) ∈ Rel` have "(!P, !Q) ∈ bangRel Rel" by(rule bangRel.BRBang)
        with `(P, Q) ∈ Rel` have "(P \<parallel> !P, Q \<parallel> !Q) ∈ bangRel Rel" by(rule bangRel.BRPar)
        then obtain P' where "P \<parallel> !P ==>α \<prec> P'" and "(P', Q') ∈ bangRel Rel'" using cBang
          by blast
        from `P \<parallel> !P ==>α \<prec> P'` have "!P ==>α \<prec> P'" by(rule weakCongRepl)
        thus ?case using `(P', Q') ∈ bangRel Rel'` by blast
      qed
    qed
  }

  moreover from `(P, Q) ∈ Rel` have "(!P, !Q) ∈ bangRel Rel" by(rule BRBang) 
  ultimately show ?case using `!Q \<longmapsto> α \<prec> Q'` by blast
qed

end